      REAL             FUNCTION SCASUM( N, CX, INCX )
*
*     takes the sum of the absolute values of a complex vector and
*     returns a single precision result.
*     jack dongarra, linpack, 3/11/78.
*
*     .. Scalar Arguments ..
      INTEGER                           INCX, N
*     ..
*     .. Array Arguments ..
      COMPLEX                           CX( 1 )
*     ..
*     .. Local Scalars ..
      INTEGER                           I, IX, NINCX
      REAL                              STEMP
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC                         ABS, AIMAG, REAL
*     ..
*     .. Executable Statements ..
*
      SCASUM = 0.0E0
      STEMP = 0.0E0
      IF( N.LE.0 )
     $   RETURN
      IF( INCX.EQ.1 )
     $   GO TO 20
*
*        code for increment not equal to 1
*
      IX = 1
      IF( INCX.LT.0 )
     $   IX = 1 - ( N-1 )*INCX
      NINCX = IX + ( N-1 )*INCX
      DO 10 I = IX, NINCX, INCX
         STEMP = STEMP + ABS( REAL( CX( I ) ) ) +
     $           ABS( AIMAG( CX( I ) ) )
   10 CONTINUE
      SCASUM = STEMP
      RETURN
*
*        code for increment equal to 1
*
   20 DO 30 I = 1, N
         STEMP = STEMP + ABS( REAL( CX( I ) ) ) +
     $           ABS( AIMAG( CX( I ) ) )
   30 CONTINUE
      SCASUM = STEMP
      RETURN
      END
